wiki:misc/processing/setup_ar

Version 5 (modified by obina, 10 years ago) (diff)

--

AR関連ソフトのセットアップ

インストール前に確認

  • Sketch → Import Librry... → で出てくる一覧を確認する
  • 画面のようにで、デフォルトで dxf, minim, net, pdf, serial, video が入っているはず。
  • Add Library .. から追加できるものもあるが、AR関連はこれとは別に手動でインストールする必要がある。

NyARToolkitのダウンロードとインストール

  • NyARToolkit http://nyatla.jp/nyartoolkit/wp/
  • ダウンロードサイト http://sourceforge.jp/projects/nyartoolkit/releases/
    • ここから Processing 用のファイルをダウンロード : nyar4psg NyARToolkit for processing
    • 現時点では nyar4psg-1.3.1.zip (2012-12-13)
  • ダウンロードしたファイルを展開し、
    • ドキュメント→Processing→libraries以下に保存
    • フォルダ名を nyar4psg に変更(ライブラリ名とフォルダ名は一致していなければいけないので)
  • Processing を実行している場合は、いちど終了して再立ち上げ。

動作確認

  • Sketch → Import Librry... → で出てくる一覧を確認する
    • Contributed の中に、nyar4psg が表示されていれば大丈夫
  • 既存プログラムの先頭に "import jp.nyatla.nyar4psg.*;" の1行を書き込んで実行。エラーがでなければライブラリは読み込めている。
  • マーカーを印刷
    • Documents\Processing\libraries\nyar4psg\examples\for2.x\pngMarker\data\hiro.png を適当な大きさで印刷

Examples で動作確認

  • Processing を実行中
  • コマンドプロンプトを開き、Documents\Processing\libraries\nyar4psg\examples\for2.x に移動
    • setup_example_pss2.bat を実行し、Enterを押す
  • File → Examples... を開き、そのなかから
    • Contributed LIbraries → nyar4psg → for2.x → simpleLite を開く
    • 日本語コメントが文字化けしているが、いまは気にしない
    • simpleLite を実行し、hiro マーカーを置くと、青色の box が出る
    • 次の例として、 rotation を実行
    • 座標軸が表示され、box が z軸まわりに回転することを確認。
    • 「人」マーカーを置く。ソースコード内で定義している左手系と右手系との差を確認。

自分で読み込んだ画像を表示:2次元の場合

  • NyARToolkitを使うため、既存の sketch_140807c の下に data, code の2つのフォルダを作成し、必要なjarファイルやデータをコピー
    • 手っ取り早くは Example (フォルダ Processing\libraries\nyar4psg\examples\for2.x\simpleLite の下にある data, code) をコピーしてしまう
  • 画像を準備
  • プログラムを作成(2つのマーカーに対し、別の画像を表示)
    import processing.video.*;
    import jp.nyatla.nyar4psg.*;
    
    Capture cam;
    MultiMarker nya;
    PImage img_jin, img_poni;
    
    void setup() {
      size(640, 480, P3D);
      String[] cameras = Capture.list();
    
      cam = new Capture(this, cameras[0]); // select cam 0
    
      nya = new MultiMarker(this,width,height,"camera_para.dat",NyAR4PsgConfig.CONFIG_PSG);
      nya.addARMarker("patt.hiro", 80);
      nya.addARMarker("patt.kanji", 80);  
      
      img_jin  = loadImage("data/jin01t.gif");
      img_poni = loadImage("data/poni01t.gif");
      
      cam.start(); // start camera  
    
    }
    
    void draw() {
      if (cam.available() != true) {
          return;
      }
      
      background(0);        // clear (black) backgound
      cam.read();           // read camera image
      nya.detect(cam);  // detect marker
      
      nya.drawBackground(cam); // draw background camera image
      if (nya.isExistMarker(0)) {
        nya.beginTransform(0);
        scale(0.25);
        rotateX(radians(-90));
        translate(-200,-400,0);
        image(img_jin, 0, 0);     // show Jin
        nya.endTransform();
      }
      if (nya.isExistMarker(1)) {
        nya.beginTransform(1);
        scale(0.25);
        rotateX(radians(-90));
        translate(-200,-400,0);
        image(img_poni, 0, 0);     // show Poni
        nya.endTransform();  
      }
     
    }
    

画像によって位置の微調整が必要。

自分で読み込んだ画像を表示:3次元の場合

3次元ファイル形式のなかで、Wavefront Obj 形式を表示するために、saitoobjloaderを使う

  • https://code.google.com/p/saitoobjloader/
  • Download ページから OBJLoader.zip version 0.23b をダウンロード
  • NyARToolkitと同様に、Document\Processing\libraries\OBJLoader に展開
  • Processingを再起動し、OBJLoaderが Library のところに表示されていることを確認
  • sketchを名前をつけて保存しなおす。今回は sketch_140807d とした
  • Documents\Processing\libraries\OBJLoader\examples\OBJLoader_Multi_Models_MATTD\data にある cassini.obj, cassini.mtl をスケッチのdataフォルダへコピーする
import processing.video.*;
import jp.nyatla.nyar4psg.*;
import saito.objloader.*;

Capture cam;
MultiMarker nya;
PImage img_jin, img_poni;
OBJModel  model;

void setup() {
  size(640, 480, P3D);

  // setup camera
  String[] cameras = Capture.list();
  cam = new Capture(this, cameras[0]); // select cam 0

  // load AR marker information
  nya = new MultiMarker(this,width,height,"camera_para.dat",NyAR4PsgConfig.CONFIG_PSG);
  nya.addARMarker("patt.hiro", 80);
  nya.addARMarker("patt.kanji", 80);  
  
  // load 2D image file
  img_jin  = loadImage("data/jin01t.gif");
  img_poni = loadImage("data/poni01t.gif");
  
  // load 3D object model
  model = new OBJModel(this);
  model.load("data/cassini.obj");
  model.scale(3.0);
  model.translateToCenter();
  
  cam.start(); // start camera  

}

void draw() {
  if (cam.available() != true) {
      return;
  }
  
  background(0);        // clear (black) backgound
  cam.read();           // read camera image
  nya.detect(cam);  // detect marker
  
  nya.drawBackground(cam); // draw background camera image
  if (nya.isExistMarker(0)) {
    nya.beginTransform(0);
    model.draw();            // show 3D Obj(Cassini)
    nya.endTransform();
  }
  if (nya.isExistMarker(1)) {
    nya.beginTransform(1);
    scale(0.25);
    rotateX(radians(-90));
    translate(-200,-400,0);
    image(img_poni, 0, 0);     // show Poni
    nya.endTransform();  
  }
 
}